    Картинка = "https://hut.openintegrations.dev/test_data/picture.jpg";
    OPI_ПреобразованиеТипов.ПолучитьДвоичныеДанные(Картинка); // Картинка - Тип: ДвоичныеДанные

    Адрес  = "127.0.0.1";
    Логин  = "bayselonarrend";
    Пароль = "12we...";
    База   = "test_data";

    TLS = Истина;
    Порт = 5432;
    СтрокаПодключения = OPI_PostgreSQL.СформироватьСтрокуПодключения(Адрес, База, Логин, Пароль, Порт);

    Если TLS Тогда
        НастройкиTLS = OPI_PostgreSQL.ПолучитьНастройкиTLS(Истина);
    Иначе
        НастройкиTLS = Неопределено;
    КонецЕсли;

    Соединение = OPI_PostgreSQL.ОткрытьСоединение(СтрокаПодключения, НастройкиTLS);

    // CREATE

    ТекстЗапроса = "
                   |CREATE TABLE test_table (
                   |id SERIAL PRIMARY KEY,
                   |name NAME,
                   |age INT,
                   |salary REAL,
                   |is_active BOOL,
                   |created_at DATE,
                   |data BYTEA
                   |);";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // INSERT с параметрами

    ТекстЗапроса = "
                   |INSERT INTO test_table (name, age, salary, is_active, created_at, data)
                   |VALUES ($1, $2, $3, $4, $5, $6);";

    МассивПараметров = Новый Массив;
    МассивПараметров.Добавить(Новый Структура("NAME" , "Vitaly"));
    МассивПараметров.Добавить(Новый Структура("INT"  , 25));
    МассивПараметров.Добавить(Новый Структура("REAL" , 1000.12));
    МассивПараметров.Добавить(Новый Структура("BOOL" , Истина));
    МассивПараметров.Добавить(Новый Структура("DATE" , OPI_Инструменты.ПолучитьТекущуюДату()));
    МассивПараметров.Добавить(Новый Структура("BYTEA", Картинка));

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, МассивПараметров, , Соединение);

    // SELECT (Результат этого запроса приведен в следующем блоке)

    ТекстЗапроса = "SELECT id, name, age, salary, is_active, created_at, data FROM test_table;";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // DO + Транзакция

    ТекстЗапроса = "DO $$
                   |BEGIN
                   |    CREATE TABLE users (
                   |        id SMALLSERIAL,
                   |        name TEXT NOT NULL,
                   |        age INT NOT NULL
                   |    );
                   |    INSERT INTO users (name, age) VALUES ('Alice', 30);
                   |    INSERT INTO users (name, age) VALUES ('Bob', 25);
                   |    INSERT INTO users (name, age) VALUES ('Charlie', 35);
                   |END $$ LANGUAGE plpgsql;";

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // SQL запрос из файла

    ФайлSQL = "https://hut.openintegrations.dev/test_data/TEST_DATA.sql"; // Двоичные данные, URL или путь к файлу

    Результат = OPI_PostgreSQL.ВыполнитьЗапросSQL(ФайлSQL, , , Соединение);

    Закрытие = OPI_PostgreSQL.ЗакрытьСоединение(Соединение);