﻿---
sidebar_position: 4
description: Выполнить запрос SQL и другие функции для работы с MySQL в Открытом пакете интеграций - бесплатной open-source библиотеке интеграций для 1С:Предприятие 8, OneScript и CLI
keywords: [1C, 1С, 1С:Предприятие, 1С:Предприятие 8.3, API, Интеграция, Сервисы, Обмен, OneScript, CLI, MySQL]
---

import Tabs from '@theme/Tabs';
import TabItem from '@theme/TabItem';

# Выполнить запрос SQL
 Выполняет произвольный SQL запрос



`Функция ВыполнитьЗапросSQL(Знач ТекстЗапроса, Знач Параметры = "", Знач ФорсироватьРезультат = Ложь, Знач Соединение = "", Знач Tls = "") Экспорт`

  | Параметр | CLI опция | Тип | Обяз. | Назначение |
  |-|-|-|-|-|
  | ТекстЗапроса | --sql | Строка | &#x2714; | Текст запроса к базе |
  | Параметры | --params | Массив Из Произвольный | &#x2716; | Массив позиционных параметров запроса |
  | ФорсироватьРезультат | --force | Булево | &#x2716; | Включает попытку получения результата, даже для не SELECT запросов |
  | Соединение | --dbc | Строка, Произвольный | &#x2716; | Соединение или строка подключения |
  | Tls | --tls | Структура Из КлючИЗначение | &#x2716; | Настройки TLS, если необходимо. См. ПолучитьНастройкиTls |

  
  Возвращаемое значение:   Соответствие Из КлючИЗначение - Результат выполнения запроса

<br/>

:::tip
Параметры запроса указываются как массив структур вида `{'Тип данных': 'Значение'}`. Список доступных типов описан на начальной странице документации библиотеки MySQL

Без указания флага `ФорсироватьРезультат`, чтение результата осуществляется только для запросов, начинающихся с `SELECT` Для остальных запросов возвращается `result:true` или `false` с текстом ошибки
:::
<br/>



```bsl title="Пример использования для 1С:Предприятие/OneScript"
    Картинка = "https://api.athenaeum.digital/test_data/picture.jpg";
    OPI_ПреобразованиеТипов.ПолучитьДвоичныеДанные(Картинка); // Картинка - Тип: ДвоичныеДанные

    Адрес  = "127.0.0.1";
    Логин  = "bayselonarrend";
    Пароль = "12we...";
    База   = "test_data";

    СтрокаПодключения = OPI_MySQL.СформироватьСтрокуПодключения(Адрес, База, Логин, Пароль);
    Соединение        = OPI_MySQL.ОткрытьСоединение(СтрокаПодключения);

    // CREATE

    ТекстЗапроса = "
                   |CREATE TABLE test_table (
                   |id INT AUTO_INCREMENT PRIMARY KEY,
                   |name VARCHAR(255),
                   |age INT,
                   |salary DOUBLE,
                   |amount FLOAT,
                   |type TINYINT UNSIGNED,
                   |date DATE,
                   |time TIME,
                   |data MEDIUMBLOB
                   |);";

    Результат = OPI_MySQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // INSERT с параметрами

    ТекстЗапроса = "
                   |INSERT INTO test_table (name, age, salary, amount, type, date, time, data)
                   |VALUES (?, ?, ?, ?, ?, ?, ?, ?);";

    МассивПараметров = Новый Массив;
    МассивПараметров.Добавить(Новый Структура("TEXT"  , "Vitaly"));
    МассивПараметров.Добавить(Новый Структура("INT"   , 25));
    МассивПараметров.Добавить(Новый Структура("DOUBLE", 1000.12));
    МассивПараметров.Добавить(Новый Структура("FLOAT" , 1000.12));
    МассивПараметров.Добавить(Новый Структура("UINT"  , 1));
    МассивПараметров.Добавить(Новый Структура("DATE"  , OPI_Инструменты.ПолучитьТекущуюДату()));
    МассивПараметров.Добавить(Новый Структура("TIME"  , OPI_Инструменты.ПолучитьТекущуюДату()));
    МассивПараметров.Добавить(Новый Структура("BYTES" , Картинка));

    Результат = OPI_MySQL.ВыполнитьЗапросSQL(ТекстЗапроса, МассивПараметров, , Соединение);

    // SELECT (Результат этого запроса приведен в следующем блоке)

    ТекстЗапроса = "SELECT name, age, salary, amount, type, date, time, data FROM test_table;";

    Результат = OPI_MySQL.ВыполнитьЗапросSQL(ТекстЗапроса, , , Соединение);

    // SQL запрос из файла

    ФайлSQL = "https://api.athenaeum.digital/test_data/TEST_DATA2.sql"; // Двоичные данные, URL или путь к файлу

    Результат = OPI_MySQL.ВыполнитьЗапросSQL(ФайлSQL, , , Соединение);

    Закрытие = OPI_MySQL.ЗакрытьСоединение(Соединение);
```
    

 <Tabs>
  
    <TabItem value="bash" label="Bash" default>
        ```bash
            oint mysql ВыполнитьЗапросSQL \
              --sql "https://github.com/Bayselonarrend/OpenIntegrations/raw/main/service/test_data/TEST_DATA2.sql" \
              --dbc "mysql://bayselonarrend:***@127.0.0.1:3306/"
        ```
    </TabItem>
  
    <TabItem value="bat" label="CMD/Bat" default>
        ```batch
            oint mysql ВыполнитьЗапросSQL ^
              --sql "https://github.com/Bayselonarrend/OpenIntegrations/raw/main/service/test_data/TEST_DATA2.sql" ^
              --dbc "mysql://bayselonarrend:***@127.0.0.1:3306/"
        ```
    </TabItem>
</Tabs>


```json title="Результат"
{
 "data": [
  {
   "age": 25,
   "amount": 1000.11999511719,
   "data": {
    "BYTES": "Base64"
   },
   "date": "2025-04-06T03:00:00+03:00",
   "name": "Vitaly",
   "salary": 1000.12,
   "time": "1970-01-01T03:23:43+03:00",
   "type": 1
  }
 ],
 "result": true
}
```
