lazarus-ccr/applications/lazstats/source/forms/analysis/measurement_programs/succintunit.pas

// Test file: sucsintv.laz, use all variables.

// TODO: Different output from OpenStat for VAR5 scale value in "Estimates of scale values..."

unit SuccIntUnit;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs,
  StdCtrls, Buttons, ExtCtrls,
  MainUnit, FunctionsLib, Globals, BasicStatsReportFormUnit;

type

  { TSuccIntFrm }

  TSuccIntFrm = class(TBasicStatsReportForm)
    InBtn: TBitBtn;
    OutBtn: TBitBtn;
    AllBtn: TBitBtn;
    Label1: TLabel;
    Label2: TLabel;
    ItemList: TListBox;
    VarList: TListBox;
    procedure AllBtnClick(Sender: TObject);
    procedure InBtnClick(Sender: TObject);
    procedure ItemListDblClick(Sender: TObject);
    procedure OutBtnClick(Sender: TObject);
    procedure VarListDblClick(Sender: TObject);
    procedure VarListSelectionChange(Sender: TObject; {%H-}User: boolean);
  private
	
  protected
    procedure AdjustConstraints; override;
    procedure Compute; override;
    procedure UpdateBtnStates; override;
    function Validate(out AMsg: String; out AControl: TWinControl): Boolean; override;
		
  public
    procedure Reset; override;
  end; 

var
  SuccIntFrm: TSuccIntFrm;

implementation

{$R *.lfm}

uses
  GridProcs;

{ TSuccIntFrm }

procedure TSuccIntFrm.AdjustConstraints;
begin
  inherited;

  ParamsPanel.Constraints.MinWidth := 4*CloseBtn.Width + 3*CloseBtn.BorderSpacing.Left;
  ParamsPanel.Constraints.MinHeight := AllBtn.Top + AllBtn.Height +
    VarList.BorderSpacing.Bottom + ButtonBevel.Height +
    CloseBtn.Height + CloseBtn.BorderSpacing.Top;
end;


procedure TSuccIntFrm.AllBtnClick(Sender: TObject);
var
  i: integer;
begin
  for i := 0 to VarList.Items.Count - 1do
    ItemList.Items.Add(VarList.Items[i]);
  VarList.Clear;
  UpdateBtnStates;
end;


procedure TSuccIntFrm.Compute;
var
  i, j, k, col, X, NoSelected, MaxCat, count, subscript: integer;
  discrow: integer;
  CatCount: IntDyneVec = nil;
  ColNoSelected: IntDyneVec = nil;
  FreqMat: IntDyneMat = nil;
  RowTots: IntDyneVec = nil;
  PropMat: DblDyneMat = nil;
  Zmatrix: DblDyneMat = nil;
  WidthMat: DblDyneMat = nil;
  TheorZMat: DblDyneMat = nil;
  ThCumPMat: DblDyneMat = nil;
  CumMat: DblDyneMat = nil;
  DiscDisp: DblDyneVec = nil;
  Mean: DblDyneVec = nil;
  StdDev: DblDyneVec = nil;
  CumWidth: DblDyneVec = nil;
  ScaleValue: DblDyneVec = nil;
  RowLabels: StrDyneVec = nil;
  ColLabels: StrDyneVec = nil;
  d1, d2, C1, L1, L2, t3, sum, discrep, z, prop, maxdiscrep: double;
  outline: string;
  found: boolean;
  lReport: TStrings;
begin
  L1 := 0.01;
  L2 := 0.99;
  maxdiscrep := 0.0;

  // Allocate space
  SetLength(DiscDisp,NoVariables);
  SetLength(ScaleValue,NoVariables);
  SetLength(RowLabels,NoVariables);
//  SetLength(ColNoSelected,NoVariables);

  // Get items selected
  NoSelected := ItemList.Items.Count;
  SetLength(ColNoSelected, NoSelected);
  for i := 0 to NoSelected-1 do
    ColNoSelected[i] := GetVariableIndex(OS3MainFrm.DataGrid, ItemList.Items[i]);
           {
  for i := 1 to NoSelected do
  begin
    for j := 1 to NoVariables do
    begin
      outline := ItemList.Items.Strings[i-1];
      if outline = OS3MainFrm.DataGrid.Cells[j,0] then ColNoSelected[i-1] := j;
    end;
  end;
  }

(*
  OutputFrm.RichEdit.Lines.Add('check of parameters');
  outline := format('No Selected = %3d',[NoSelected]);
  OutputFrm.RichEdit.Lines.Add(outline);
  for i := 1 to NoSelected do
  begin
       outline := format('ItemList %d = %s',[i-1,ItemList.Items.Strings[i-1]]);
       OutputFrm.RichEdit.Lines.Add(outline);
       outline := format('Col. No. Selected %3d = %3d',[i-1,ColNoSelected[i-1]]);
       OutputFrm.RichEdit.Lines.Add(outline);
  end;
  OutputFrm.ShowModal;
  OutputFrm.RichEdit.Clear;
*)

  //Find largest category value in data
  MaxCat := 0;
  for j := 0 to NoSelected-1 do
  begin
    X := round(GetColMax(OS3MainFrm.DataGrid, ColNoSelected[j], ColNoSelected));
    if X > MaxCat then MaxCat := X;
  end;
  {
  GetColMax(OS3MainFrm.DataGrid,
  for i := 1 to NoCases do
  begin
    if (not GoodRecord(OS3MainFrm.DataGrid, i, ColNoSelected)) then continue;
    for j := 1 to NoSelected do
    begin
      col := ColNoSelected[j-1];
      X := round(StrToFloat(Trim(OS3MainFrm.DataGrid.Cells[col,i])));
      if (X > MaxCat) then MaxCat := X;
    end;
  end;
  }

  // Initialize arrays
  SetLength(CatCount, MaxCat);
  SetLength(FreqMat, NoVariables, MaxCat);
  SetLength(RowTots, NoVariables);
  SetLength(PropMat, NoVariables, MaxCat);
  SetLength(Zmatrix, NoVariables, MaxCat);
  SetLength(WidthMat, NoVariables, MaxCat);
  SetLength(TheorZMat, NoVariables, MaxCat);
  SetLength(ThCumPMat, NoVariables, MaxCat);
  SetLength(CumMat, NoVariables, MaxCat);
  SetLength(Mean, MaxCat);
  SetLength(StdDev, MaxCat);
  SetLength(CumWidth, MaxCat);
  SetLength(ColLabels, MaxCat);

  // Build frequency matrix
  for i := 0 to NoCases-1 do
  begin
    if (not GoodRecord(OS3MainFrm.DataGrid, i+1, ColNoSelected)) then continue;
    for j := 0 to NoSelected-1 do
    begin
      col := ColNoSelected[j];
      X := round(StrToFloat(Trim(OS3MainFrm.DataGrid.Cells[col, i+1])));
      if (X > 0) and (X <= MaxCat) then
        FreqMat[j, X-1] := FreqMat[j, X-1] + 1;
    end;
  end;

  // Get row totals of the frequency matrix
  for i := 0 to NoSelected-1 do
  begin
    RowTots[i] := 0;
    for j := 0 to MaxCat-1 do
      RowTots[i] := RowTots[i] + FreqMat[i, j];
  end;

  // Convert frequencies to proportions of the row totals
  for i := 0 to NoSelected-1 do
    for j := 0 to MaxCat-1 do
      PropMat[i, j] := FreqMat[i, j] / RowTots[i];

  // Accumulate the proportions accross the categories
  for i := 1 to NoSelected do
  begin
    CumMat[i-1,0] := PropMat[i-1,0];
    for j := 2 to MaxCat do
    begin
      CumMat[i-1, j-1] := CumMat[i-1, j-2] + PropMat[i-1, j-1];
      if (j = MaxCat) then
        CumMat[i-1, j-1] := 1.0;
    end;
  end;

  // Convert cumulative proportions to z scores
  for i := 0 to NoSelected-1 do
  begin
    for j := 0 to MaxCat-1 do
    begin
      if (CumMat[i,j] < L1) then Zmatrix[i,j] := 99.0; //flag  -infinity
      if (CumMat[i,j] > L2) then Zmatrix[i,j] := 99.0; //flag +infinity
      if ((CumMat[i,j] >= L1) and (CumMat[i,j] <= L2)) then
        Zmatrix[i,j] := inversez(CumMat[i,j]);
    end;
  end;

  // Obtain discriminal dispersions of the items
  t3 := 0.0;
  for i := 1 to NoSelected do
  begin
    d1 := 0.0;
    d2 := 0.0;
    C1 := 0.0;
    for j := 1 to MaxCat - 1 do
    begin
      if (Zmatrix[i-1,j-1] <> 99.0) then
      begin
        d1 := d1 + Zmatrix[i-1,j-1];
        d2 := d2 + (Zmatrix[i-1,j-1] * Zmatrix[i-1,j-1]);
        C1 := C1 + 1.0;
      end;
    end;
    if (C1 > 1) then
    begin
      DiscDisp[i-1] := d2 - (d1 * d1) / C1;
      DiscDisp[i-1] := DiscDisp[i-1] / (C1-1.0);
      DiscDisp[i-1] := sqrt(DiscDisp[i-1]);
    end else
      DiscDisp[i-1] := 99.0;
    if (DiscDisp[i-1] > 0) and (DiscDisp[i-1] <> 99.0) then
      t3 := t3 + 1.0/DiscDisp[i-1];
  end;

  //Constant t3 =No. items / recipricols of std.dev.s of item z scores
  t3 := NoSelected / t3;
  for i := 0 to NoSelected-1 do
  begin
    if (DiscDisp[i] > 0.0) and (t3 > 0) then
      DiscDisp[i] := (1.0 / DiscDisp[i]) * t3
    else
      DiscDisp[i] := 99.0;
  end;

  // Now, calculate interval widths
  for j := 2 to MaxCat - 1 do
  begin
    for i := 0 to NoSelected-1 do
    begin
      if (Zmatrix[i, j-1] <> 99.0) and (Zmatrix[i, j-2] <> 99.0) then
        WidthMat[i, j-2] := Zmatrix[i, j-1] - Zmatrix[i, j-2]
      else
        WidthMat[i, j-2] := 99.0;
    end;
  end;

  //Calculate Means and Standard Deviations of category Widths
  for j := 1 to MaxCat-2 do
  begin
    for i := 0 to NoSelected-1 do
    begin
      if (WidthMat[i,j-1] <> 99.0) then
      begin
        CatCount[j-1] := CatCount[j-1] + 1;
        Mean[j-1] := Mean[j-1] + WidthMat[i, j-1];
        StdDev[j-1] := StdDev[j-1] + (WidthMat[i, j-1] * WidthMat[i, j-1]);
      end;
    end;
    if (CatCount[j-1] > 1) then
    begin
      Mean[j-1] := Mean[j-1] / CatCount[j-1];
      StdDev[j-1] := (StdDev[j-1] / CatCount[j-1]) - (Mean[j-1] * Mean[j-1]);
      StdDev[j-1] := StdDev[j-1] * (CatCount[j-1] / (CatCount[j-1] - 1));
    end;
  end;

  // Calculate cumulative widths
  CumWidth[0] := Mean[0];
  for j := 2 to MaxCat - 1 do
    CumWidth[j-1] := CumWidth[j-2] + Mean[j-1];

  // Calculate scale item scale values
  for i := 1 to NoSelected do
  begin
    found := false;
    count := 1;
    while (not found) do
    begin
      if CumMat[i-1,count-1] >= 0.5 then
      begin
        found := true;
        subscript := count;
      end;
      if (count = (MaxCat)) then
      begin
        found := true;
        subscript := count;
      end;
      count := count + 1;
    end;

    if (subscript > 2) and (subscript < MaxCat) then
    begin
      ScaleValue[i-1] := Mean[subscript-2] * ((0.5 - CumMat[i-1,subscript-2]) / PropMat[i-1,subscript-1]);
      if (subscript > 1) then
        ScaleValue[i-1] := ScaleValue[i-1] + CumWidth[subscript-3];
    end
    else
    begin  //extreme value - get average of z scores in first cat. and / 2
      sum := 0.0;
      for k := 1 to NoSelected do
        sum := sum + Zmatrix[i-1,0];
      sum := sum / abs(NoSelected * 2);
      ScaleValue[i-1] := sum * ((0.5 - (CumMat[i-1,0] / 2.0)) / (CumMat[i-1,0] / 2.0));
    end;
  end;

  //Calculate Theoretical z scores from the scale values
  discrep := 0.0;
  count := 0;
  for i := 1 to NoSelected do
  begin
    z := -ScaleValue[i-1];
    TheorZMat[i-1,0] := z;
    prop := probz(z);
    ThCumPMat[i-1,0] := prop;
    for j := 2 to MaxCat - 1 do
    begin
      z := CumWidth[j-2] - ScaleValue[i-1];
      if (z < -3) then z := -3.0;
      if (z > 3) then z := 3.0;
      prop := probz(z);
      TheorZMat[i-1,j-1] := z;
      ThCumPMat[i-1,j-1] := prop;
      discrep := discrep + abs(CumMat[i-1,j-1] - prop);
      if abs(CumMat[i-1,j-1] - prop) > maxdiscrep then
      begin
        maxdiscrep := abs(CumMat[i-1,j-1] - prop);
        discrow := i;
      end;
      count := count + 1;
    end;
    ThCumPMat[i-1, MaxCat-1] := 1.0;
  end;
  discrep := discrep / count; // average discrepency between theoretical and observed

  // Report results
  lReport := TStringList.Create;
  try
    lReport.Add('SUCCESSIVE INTERVAL SCALING RESULTS');
    lReport.Add('');
    for i := 0 to NoSelected-1 do
      RowLabels[i] := OS3MainFrm.DataGrid.Cells[ColNoSelected[i],0];
    for i := 0 to MaxCat-1 do
      ColLabels[i] := Format('  %2d-%2d ', [i, i+1]);

    outline := '            ';
    for i := 0 to MaxCat-1 do outline := outline + ColLabels[i];
    lReport.Add(outline);
    outline := '            ';
    for i := 0 to MaxCat-1 do outline := outline + ' ------ ';
    lReport.Add(outline);

    for i := 0 to NoSelected-1 do
    begin
      if i > 0 then
        lReport.Add('');
      lReport.Add('%10s', [RowLabels[i]]);

      outline := 'Frequency  ';
      for j := 0 to MaxCat-1 do
        outline := outline + Format('%8d', [FreqMat[i, j]]);
      lReport.Add(outline);

      outline := 'Proportion ';
      for j := 0 to MaxCat-1 do
        outline := outline + Format('%8.3f', [PropMat[i, j]]);
      lReport.Add(outline);

      outline := 'Cum. Prop. ';
      for j := 0 to MaxCat-1 do
        outline := outline + Format('%8.3f', [CumMat[i, j]]);
      lReport.Add(outline);

      outline := 'Normal z   ';
      for j := 0 to MaxCat-1 do
      begin
        if (Zmatrix[i, j] <> 99.0) then
          outline := outline + Format('%8.3f', [Zmatrix[i, j]])
        else
          outline := outline + '       -';
      end;
      lReport.Add(outline);
    end;

    lReport.Add('');
    lReport.Add(DIVIDER_SMALL);
    lReport.Add('');

    lReport.Add('INTERVAL WIDTHS');
    lReport.Add('');
    outline := '            ';
    for i := 1 to MaxCat - 2 do
      outline := outline + Format('  %2d-%2d ', [i+1,i]);
    lReport.Add(outline);
    outline := '            ';
    for i := 1 to MaxCat - 2 do
      outline := outline + ' ------ ';
    lReport.Add(outline);

    outline := '';
    for i := 0 to NoSelected-1 do
    begin
      outline := outline + Format('%11s', [RowLabels[i]]);
      for j := 0 to MaxCat-3 do
      begin
        if (WidthMat[i, j] <> 99.0) then
          outline := outline + Format('%8.3f', [WidthMat[i, j]])
        else
          outline := outline + '       -';
      end;
      lReport.Add(outline);
      outline := '';
    end;
    lReport.Add('');

    outline := 'Mean Width ';
    for i := 0 to MaxCat - 3 do
      outline := outline + Format('%8.2f', [Mean[i]]);
    lReport.Add(outline);

    outline := 'No. Items  ';
    for i := 0 to MaxCat - 3 do
      outline := outline + Format('%8d', [CatCount[i]]);
    lReport.Add(outline);

    outline := 'Std. Dev.s ';
    for i := 0 to MaxCat - 3 do
      outline := outline + Format('%8.2f', [StdDev[i]]);;
    lReport.Add(outline);

    outline := 'Cum. Means ';
    for i := 0 to MaxCat - 3 do
      outline := outline + Format('%8.2f', [CumWidth[i]]);
    lReport.Add(outline);

    lReport.Add('');
    lReport.Add(DIVIDER_SMALL);
    lReport.Add('');

    lReport.Add('ESTIMATES OF SCALE VALUES AND THEIR DISPERSIONS');
    lReport.Add('');
    lReport.Add('   Item      No. Ratings   Scale Value   Discriminal Dispersion');
    lReport.Add('----------   -----------   -----------   ----------------------');
    //             xxxxxxx          xxxx      xxxxxxxx           xxxxxxxx
    for i := 0 to NoSelected-1 do
      lReport.Add('%7s          %4d      %8.3f           %8.3f', [RowLabels[i], RowTots[i], ScaleValue[i], DiscDisp[i]]);
    lReport.Add('');

    lReport.Add('Z scores Estimated from Scale values');
    lReport.Add('');
    outline := '           ';
    for i := 0 to MaxCat-1 do outline := outline + ColLabels[i];
    lReport.Add(outline);
    outline := '           ';
    for i := 0 to MaxCat-1 do outline := outline + ' ------ ';
    lReport.Add(outline);
    for i := 0 to NoSelected-1 do
    begin
      outline :=  Format('%10s', [RowLabels[i]]);
      for j := 0 to MaxCat - 2 do
        outline := outline + Format('%8.3f', [TheorZMat[i, j]]);
      lReport.Add(outline);
    end;

    lReport.Add('');
    lReport.Add(DIVIDER_SMALL);
    lReport.Add('');

    lReport.Add('CUMULATIVE THEORETICAL PROPORTIONS');
    lReport.Add('');
    outline := '           ';
    for i := 0 to MaxCat-1 do outline := outline + ColLabels[i];
    lReport.Add(outline);
    outline := '           ';
    for i := 0 to MaxCat-1 do outline := outline + ' ------ ';
    lReport.Add(outline);
    for i := 0 to NoSelected-1 do
    begin
      outline :=  Format('%10s', [RowLabels[i]]);
      for j := 0 to MaxCat-1 do
        outline := outline + Format('%8.3f', [ThCumPMat[i, j]]);
      lReport.Add(outline);
    end;
    lReport.Add('');

    lReport.Add('Average Discrepancy Between Theoretical and Observed Cumulative Proportions: %.3f', [discrep]);
    lReport.Add('Maximum discrepancy %.3f found in item %s', [maxdiscrep, RowLabels[discrow-1]]);

    FReportFrame.DisplayReport(lReport);

  finally
    lReport.Free;
  end;
end;


procedure TSuccIntFrm.InBtnClick(Sender: TObject);
var
  i: integer;
begin
  i := 0;
  while i < VarList.Items.Count do
  begin
    if VarList.Selected[i] then
    begin
      ItemList.Items.Add(VarList.Items[i]);
      VarList.Items.Delete(i);
      i := 0;
    end else
      inc(i);
  end;
  UpdateBtnStates;
end;


procedure TSuccIntFrm.ItemListDblClick(Sender: TObject);
var
  index: Integer;
begin
  index := ItemList.ItemIndex;
  if index > -1 then
  begin
    VarList.Items.Add(ItemList.Items[index]);
    ItemList.Items.Delete(index);
    UpdateBtnStates;
  end;
end;


procedure TSuccIntFrm.OutBtnClick(Sender: TObject);
var
  i: integer;
begin
  i := 0;
  while i < ItemList.Items.Count do
  begin
    if ItemList.Selected[i] then
    begin
      VarList.Items.Add(ItemList.Items[i]);
      ItemList.Items.Delete(i);
      i := 0;
    end else
      inc(i);
  end;
  UpdateBtnStates;
end;


procedure TSuccIntFrm.Reset;
var
  i: integer;
begin
 inherited;
  ItemList.Clear;
  VarList.Clear;
  for i := 1 to NoVariables do
    VarList.Items.Add(OS3MainFrm.DataGrid.Cells[i,0]);
  UpdateBtnStates;
end;


procedure TSuccIntFrm.UpdateBtnStates;
var
  lSelected: Boolean;
  i: Integer;
begin
  inherited;
	
  lSelected := false;
  for i := 0 to VarList.Items.Count - 1 do
    if VarList.Selected[i] then
    begin
      lSelected := true;
      break;
    end;
  InBtn.Enabled := lSelected;

  lSelected := false;
  for i := 0 to ItemList.Items.Count -1 do
    if ItemList.Selected[i] then
    begin
      lSelected := true;
      break;
    end;
  OutBtn.Enabled := lSelected;

  AllBtn.Enabled := VarList.Items.Count > 0;
end;


function TSuccIntFrm.Validate(out AMsg: String;
  out AControl: TWinControl): Boolean;
begin
  Result := false;

  if ItemList.Items.Count = 0 then
  begin
    AMsg := 'No variables selected.';
    AControl := VarList;
    exit;
  end;

  Result := true;
end;


procedure TSuccIntFrm.VarListDblClick(Sender: TObject);
var
  index: Integer;
begin
  index := VarList.ItemIndex;
  if index > -1 then
  begin
    ItemList.Items.Add(VarList.Items[index]);
    VarList.Items.Delete(index);
    UpdateBtnStates;
  end;
end;


procedure TSuccIntFrm.VarListSelectionChange(Sender: TObject; User: boolean);
begin
  UpdateBtnStates;
end;


end.