Add documentation about our release process (#1159)

* Add documentation about our release process * Fixes * Add company-related tasks, enable back WIP pages * Fix WIP links * Add AOSC OS * Add WIP for AOSC OS * Tweak * Remove maintainers email IDs * Use GH nicknames * Remove useless WIP for brew * Tweaks
2026-06-20 11:32:56 +02:00 · 2021-10-06 16:45:44 +02:00
parent 93114072c8
commit 7989e438d2
27 changed files with 883 additions and 18 deletions
@@ -0,0 +1,2 @@
+DIST httpie-2.4.0.tar.gz 1772537 BLAKE2B 111451cc7dc353d5b586554f98ac715a3198f03e74d261944a5f021d2dcc948455500800222b323d182a2a067d0549bda7c318ab3a6c934b9a9beec64aff2db2 SHA512 44cc7ff4fe0f3d8c53a7dd750465f6b56c36f5bbac06d22b760579bd60949039e82313845699669a659ec91adc69dbeac22c06ddd63af64e6f2e0edecf3e732a
+DIST httpie-2.5.0.tar.gz 1105177 BLAKE2B 6e16868c81522d4e6d2fc0a4e093c190f18ced720b35217930865ae3f8e168193cc33dfecc13c5d310f52647d6e79d17b247f56e56e8586d633a2d9502be66a7 SHA512 f14aa23fea7578181b9bd6ededea04de9ddf0b2f697b23f76d2d96e2c17b95617318c711750bad6af550400dbc03732ab17fdf84e59d577f33f073e600a55330
@@ -0,0 +1,78 @@
+# HTTPie on Gentoo
+
+Welcome to the documentation about **packaging HTTPie for Gentoo**.
+
+- If you do not know HTTPie, have a look [here](https://httpie.io/cli).
+- If you are looking for HTTPie installation or upgrade instructions on Gentoo, then you can find them on [that page](https://httpie.io/docs#gentoo).
+- If you are looking for technical information about the HTTPie packaging on Gentoo, then you are in a good place.
+
+## About
+
+This document contains technical details, where we describe how to create a patch for the latest HTTPie version for Gentoo.
+We will discuss setting up the environment, installing development tools, installing and testing changes before submitting a patch downstream.
+
+## Overall process
+
+Open a pull request to create `httpie-XXX.ebuild` and update `Manifest`.
+
+- Here is how to calculate the size and checksum (replace `2.5.0` with the correct version):
+
+  ```bash
+  # Download
+  $ wget https://github.com/httpie/httpie/archive/2.5.0.tar.gz
+
+  # Size
+  $ stat --printf="%s\n" 2.5.0.tar.gz
+  1105177
+
+  # Checksum
+  $ openssl dgst -blake2b512 2.5.0.tar.gz
+  BLAKE2b512(2.5.0.tar.gz)= 6e16868c81522d4e6d2fc0a4e093c190f18ced720b35217930865ae3f8e168193cc33dfecc13c5d310f52647d6e79d17b247f56e56e8586d633a2d9502be66a7
+  ```
+
+- The commit message must be `net-misc/httpie: version bump to XXX`.
+- The commit must be signed-off (`git commit -s`).
+
+## Hacking
+
+Launch the docker image:
+
+```bash
+docker pull gentoo/stage3
+docker run -it --rm gentoo/stage3
+```
+
+From inside the container:
+
+```bash
+# Install tools
+emerge --sync
+emerge pkgcheck repoman
+
+# Go to the package location
+cd /var/db/repos/gentoo/net-misc/httpie
+
+# Retrieve the patch of the latest HTTPie version
+# (only files that were modified since the previous release)
+curl https://raw.githubusercontent.com/httpie/httpie/master/docs/packaging/linux-gentoo/httpie-XXX.ebuild \
+  -o httpie-XXX.ebuild
+curl https://raw.githubusercontent.com/httpie/httpie/master/docs/packaging/linux-gentoo/Manifest \
+  -o Manifest
+curl https://raw.githubusercontent.com/httpie/httpie/master/docs/packaging/linux-gentoo/metadata.xml \
+  -o metadata.xml
+
+# Basic checks
+repoman manifest
+repoman full -d -x
+pkgcheck scan
+
+# Build and install the package
+emerge --with-test-deps httpie-XXX.ebuild
+
+# Run the tests suite
+ebuild httpie-XXX.ebuild clean test
+
+# And test it!
+http --version
+https --version
+```
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Modern command line HTTP client"
+HOMEPAGE="https://httpie.io/ https://pypi.org/project/httpie/"
+SRC_URI="https://github.com/httpie/httpie/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.9.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	newbashcomp extras/httpie-completion.bash http
+	insinto /usr/share/fish/vendor_completions.d
+	newins extras/httpie-completion.fish http.fish
+	distutils-r1_python_install_all
+}
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>mickael@apible.io</email>
+		<name>Mickaël Schoentgen</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<longdescription lang="en">
+		HTTPie (pronounced aitch-tee-tee-pie) is a command line HTTP
+		client. Its goal is to make CLI interaction with web services as
+		human-friendly as possible. It provides a simple http command
+		that allows for sending arbitrary HTTP requests using a simple
+		and natural syntax, and displays colorized output. HTTPie can be
+		used for testing, debugging, and generally interacting with HTTP
+		servers.
+	</longdescription>
+	<upstream>
+		<bugs-to>https://github.com/httpie/httpie/issues</bugs-to>
+		<changelog>https://raw.githubusercontent.com/httpie/httpie/master/CHANGELOG.md</changelog>
+		<doc>https://httpie.io/docs</doc>
+		<remote-id type="github">httpie/httpie</remote-id>
+		<remote-id type="pypi">httpie</remote-id>
+	</upstream>
+</pkgmetadata>