mirror of
https://github.com/FFmpeg/FFmpeg.git
synced 2024-11-26 19:01:44 +02:00
3174616f59
* commit '6860b4081d046558c44b1b42f22022ea341a2a73': x86: include x86inc.asm in x86util.asm cng: Reindent some incorrectly indented lines cngdec: Allow flushing the decoder cngdec: Make the dbov variable have the right unit cngdec: Fix the memset size to cover the full array cngdec: Update the LPC coefficients after averaging the reflection coefficients configure: fix print_config() with broke awks Conflicts: libavcodec/x86/ac3dsp.asm libavcodec/x86/dct32.asm libavcodec/x86/deinterlace.asm libavcodec/x86/dsputil.asm libavcodec/x86/dsputilenc.asm libavcodec/x86/fft.asm libavcodec/x86/fmtconvert.asm libavcodec/x86/h264_chromamc.asm libavcodec/x86/h264_deblock.asm libavcodec/x86/h264_deblock_10bit.asm libavcodec/x86/h264_idct.asm libavcodec/x86/h264_idct_10bit.asm libavcodec/x86/h264_intrapred.asm libavcodec/x86/h264_intrapred_10bit.asm libavcodec/x86/h264_weight.asm libavcodec/x86/vc1dsp.asm libavcodec/x86/vp3dsp.asm libavcodec/x86/vp56dsp.asm libavcodec/x86/vp8dsp.asm Merged-by: Michael Niedermayer <michaelni@gmx.at>
89 lines
2.4 KiB
NASM
89 lines
2.4 KiB
NASM
;******************************************************************************
|
|
;* V210 SIMD unpack
|
|
;* Copyright (c) 2011 Loren Merritt <lorenm@u.washington.edu>
|
|
;* Copyright (c) 2011 Kieran Kunhya <kieran@kunhya.com>
|
|
;*
|
|
;* This file is part of Libav.
|
|
;*
|
|
;* Libav is free software; you can redistribute it and/or
|
|
;* modify it under the terms of the GNU Lesser General Public
|
|
;* License as published by the Free Software Foundation; either
|
|
;* version 2.1 of the License, or (at your option) any later version.
|
|
;*
|
|
;* Libav is distributed in the hope that it will be useful,
|
|
;* but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;* Lesser General Public License for more details.
|
|
;*
|
|
;* You should have received a copy of the GNU Lesser General Public
|
|
;* License along with Libav; if not, write to the Free Software
|
|
;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
|
|
;******************************************************************************
|
|
|
|
%include "libavutil/x86/x86util.asm"
|
|
|
|
SECTION_RODATA
|
|
|
|
v210_mask: times 4 dd 0x3ff
|
|
v210_mult: dw 64,4,64,4,64,4,64,4
|
|
v210_luma_shuf: db 8,9,0,1,2,3,12,13,4,5,6,7,-1,-1,-1,-1
|
|
v210_chroma_shuf: db 0,1,8,9,6,7,-1,-1,2,3,4,5,12,13,-1,-1
|
|
|
|
SECTION .text
|
|
|
|
%macro v210_planar_unpack 2
|
|
|
|
; v210_planar_unpack(const uint32_t *src, uint16_t *y, uint16_t *u, uint16_t *v, int width)
|
|
cglobal v210_planar_unpack_%1_%2, 5, 5, 7
|
|
movsxdifnidn r4, r4d
|
|
lea r1, [r1+2*r4]
|
|
add r2, r4
|
|
add r3, r4
|
|
neg r4
|
|
|
|
mova m3, [v210_mult]
|
|
mova m4, [v210_mask]
|
|
mova m5, [v210_luma_shuf]
|
|
mova m6, [v210_chroma_shuf]
|
|
.loop
|
|
%ifidn %1, unaligned
|
|
movu m0, [r0]
|
|
%else
|
|
mova m0, [r0]
|
|
%endif
|
|
|
|
pmullw m1, m0, m3
|
|
psrld m0, 10
|
|
psrlw m1, 6 ; u0 v0 y1 y2 v1 u2 y4 y5
|
|
pand m0, m4 ; y0 __ u1 __ y3 __ v2 __
|
|
|
|
shufps m2, m1, m0, 0x8d ; y1 y2 y4 y5 y0 __ y3 __
|
|
pshufb m2, m5 ; y0 y1 y2 y3 y4 y5 __ __
|
|
movu [r1+2*r4], m2
|
|
|
|
shufps m1, m0, 0xd8 ; u0 v0 v1 u2 u1 __ v2 __
|
|
pshufb m1, m6 ; u0 u1 u2 __ v0 v1 v2 __
|
|
movq [r2+r4], m1
|
|
movhps [r3+r4], m1
|
|
|
|
add r0, mmsize
|
|
add r4, 6
|
|
jl .loop
|
|
|
|
REP_RET
|
|
%endmacro
|
|
|
|
INIT_XMM
|
|
v210_planar_unpack unaligned, ssse3
|
|
%if HAVE_AVX_EXTERNAL
|
|
INIT_AVX
|
|
v210_planar_unpack unaligned, avx
|
|
%endif
|
|
|
|
INIT_XMM
|
|
v210_planar_unpack aligned, ssse3
|
|
%if HAVE_AVX_EXTERNAL
|
|
INIT_AVX
|
|
v210_planar_unpack aligned, avx
|
|
%endif
|