virtualenv/FFmpeg
1
0
Fork 0
mirror of https://github.com/FFmpeg/FFmpeg.git synced 2025-08-10 06:10:52 +02:00
Code Issues Releases Activity

lavc/aarch64: Add neon implementation for vsad_intra16

Browse Source 
Provide optimized implementation for vsad_intra16 function for arm64.

Performance comparison tests are shown below.
- vsad_4_c: 177.5
- vsad_4_neon: 23.5

Benchmarks and tests are run with checkasm tool on AWS Gravtion 3.

Signed-off-by: Hubert Mazur <hum@semihalf.com>
Signed-off-by: Martin Storsjö <martin@martin.st>
This commit is contained in:
Hubert Mazur
2022-09-08 11:25:05 +02:00
committed by Martin Storsjö
parent c495a4b32d
commit ce03ea3e79
2 changed files with 51 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

3
libavcodec/aarch64/me_cmp_init_aarch64.c
View File

@@ -43,6 +43,8 @@ int sse4_neon(MpegEncContext *v, const uint8_t *pix1, const uint8_t *pix2,
int vsad16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2, int vsad16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2,
ptrdiff_t stride, int h); ptrdiff_t stride, int h);
int vsad_intra16_neon(MpegEncContext *c, const uint8_t *s, const uint8_t *dummy,
ptrdiff_t stride, int h) ;
int vsse16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2, int vsse16_neon(MpegEncContext *c, const uint8_t *s1, const uint8_t *s2,
ptrdiff_t stride, int h); ptrdiff_t stride, int h);
@@ -64,6 +66,7 @@ av_cold void ff_me_cmp_init_aarch64(MECmpContext *c, AVCodecContext *avctx)
c->sse[2] = sse4_neon; c->sse[2] = sse4_neon;
c->vsad[0] = vsad16_neon; c->vsad[0] = vsad16_neon;
c->vsad[4] = vsad_intra16_neon;
c->vsse[0] = vsse16_neon; c->vsse[0] = vsse16_neon;
} }

48
libavcodec/aarch64/me_cmp_neon.S
View File

@@ -736,3 +736,51 @@ function vsse16_neon, export=1
ret ret
endfunc endfunc
function vsad_intra16_neon, export=1
// x0 unused
// x1 uint8_t *pix1
// x2 uint8_t *dummy
// x3 ptrdiff_t stride
// w4 int h
ld1 {v0.16b}, [x1], x3
sub w4, w4, #1 // we need to make h-1 iterations
cmp w4, #3
movi v16.8h, #0
b.lt 2f
// make 4 iterations at once
1:
// v = abs( pix1[0] - pix1[0 + stride] )
// score = sum(v)
ld1 {v1.16b}, [x1], x3
ld1 {v2.16b}, [x1], x3
uabal v16.8h, v0.8b, v1.8b
ld1 {v3.16b}, [x1], x3
uabal2 v16.8h, v0.16b, v1.16b
sub w4, w4, #3
uabal v16.8h, v1.8b, v2.8b
cmp w4, #3
uabal2 v16.8h, v1.16b, v2.16b
mov v0.16b, v3.16b
uabal v16.8h, v2.8b, v3.8b
uabal2 v16.8h, v2.16b, v3.16b
b.ge 1b
cbz w4, 3f
// iterate by one
2:
ld1 {v1.16b}, [x1], x3
subs w4, w4, #1
uabal v16.8h, v0.8b, v1.8b
uabal2 v16.8h, v0.16b, v1.16b
mov v0.16b, v1.16b
cbnz w4, 2b
3:
uaddlv s17, v16.8h
fmov w0, s17
ret
endfunc